Self-Updated Webtoon Tracker

How to use this tracker

Hi!, I'm Millius :D

Some of you asked for the template to the Self-Updated Webtoon tracker, so here it is.

Keep in mind that it might not look exactly like the one I posted because I used Notion Enhancer, which you can find in here: Notion Enhancer

If something is not working properly, or you need a better explanation of something, feel free to PM me in my reddit

⚠️

This tracker does NOT scrape the Webtoon app/page to check for updates, but is based on the upload patterns that are common in there.

Right now it has the Webtoons that I am reading or wanting to read, you can just select them and press del to delete them, but I think i have good taste so first check them out haha, and if you think I'll like a webtoon that isn't there, PM me bc I'm desperate to find new things to read even though I haven't finished most lol.

How to use it

Add a new record with the template "Webtoon" (It has the relation to Stats by default) and configure the attributes according to the case. Add a cover so it shows in the gallery view. If you want to edit it, change the view of the database to "Configuration", I find it easier this way.

Editable Attributes

Type: Right now it only works with "Daily Pass" (a new chapter every day), "Fast Pass" (a new chapter every week) and "Completed" (no updates).

Chapters at Start Date: Here you put the last chapter's number that was updated, I recommend putting the second last just to check if it is doing the correct calculations (and of course, with the date of the second last). If the webtoon is completed, put the total chapters here plz (It doesn´t work if you put it anywhere else and honestly I don't have the time to check it, sorry)

Start Date: Here you can put the date in which the chapter was uploaded, you can put also time if you want it to be more specific, but it's not necessary :)

ChaptersPerCycle: Some webtoons update more than once chapter a week, it may not be the most accurate here, but it works in the long run.

Read Chapters: Well... The chapters you've read so far :p

maxChapters: It is a limit, the Total Chapters can't go beyond that, useful for the Daily Pass ones.

Priority?: It's just for sorting purposes, it gives it priority over webtoons of it's same type, you can ignore it if you want.

Formulas

Total Chapters

It should show the total chapters that are available to you right now. Make sure it shows the right number when you configure it, otherwise you'll have problems

min(if(prop("Type") == "Completed", prop("Chapters at StartDate"), prop("Chapters at StartDate") + dateBetween(now(), prop("Start Date"), if(prop("Type") == "Fast Pass", "weeks", "days")) * if(empty(prop("ChaptersPerCycle")), 1, prop("ChaptersPerCycle"))), empty(prop("maxChapters")) ? 10000000000000000 : prop("maxChapters"))

What this does is check if it is completed (Type of webtoon, not if you read it), if it is, then it will show the "Chapters at StartDate", else it will add "ChaptersPerCycle" every week or day depending on the type. Finally, it checks that it never surpases "maxChapters", or 10000000000000000 if you leave it empty (I highly doubt any webtoon gets to that, but if it does, just add a zero :p)

Progress Bar

This shows the progress in a bar (...sorry), and at the end the chapters you've read vs the total chapters. If you've read them all, it will show a message saying "✅ Read X Chapters"

if(prop("Read Chapters") / prop("Total Chapters") >= 1, "✅ Read " + format(prop("Read Chapters")) + " Chapters", format(replaceAll(slice("xxxxxxxxxx", 0, floor(prop("Read Chapters") / prop("Total Chapters") * 10)), "x", "▮") + format(replaceAll(slice("xxxxxxxxxx", 0, ceil(10 - prop("Read Chapters") / prop("Total Chapters") * 10)), "x", "▯"))) + concat(" ", format(empty(prop("Read Chapters")) ? 0 : prop("Read Chapters")), "/", format(prop("Total Chapters"))))

The original code was taken from here

Next Neu Chapter

I'm not exactly proud of this one, I used it in some formulas and then deleted it, but now it serves for sorting purposes so It will just stay there for now haha.

if(prop("Type") == "Completed", prop("Start Date"), if(prop("Type") == "Fast Pass", dateAdd(dateAdd(dateSubtract(dateAdd(dateAdd(dateSubtract(dateSubtract(prop("Start Date"), hour(prop("Start Date")), "hours"), minute(prop("Start Date")), "minutes"), 1, "days"), dateBetween(now(), dateAdd(dateSubtract(dateSubtract(prop("Start Date"), hour(prop("Start Date")), "hours"), minute(prop("Start Date")), "minutes"), 1, "days"), "weeks") + 1, "weeks"), 1, "days"), hour(prop("Start Date")), "hours"), minute(prop("Start Date")), "minutes"), if(prop("Type") == "Daily Pass", dateAdd(dateAdd(dateSubtract(dateAdd(dateAdd(dateSubtract(dateSubtract(prop("Start Date"), hour(prop("Start Date")), "hours"), minute(prop("Start Date")), "minutes"), 1, "days"), dateBetween(now(), dateAdd(dateSubtract(dateSubtract(prop("Start Date"), hour(prop("Start Date")), "hours"), minute(prop("Start Date")), "minutes"), 1, "days"), "days") + 1, "days"), 1, "days"), hour(prop("Start Date")), "hours"), minute(prop("Start Date")), "minutes"), prop("Start Date"))))

The original code came from here

Importance

Also serves for sorting purposes, Daily Pass are the most important, next the Fast Pass and lastly the Completed, the "Priority?" Checkbox gives it priority over it's own type (I already said it, but whatever). Feel free to change it to your own taste

(prop("Priority?") ? 2 : 0) + ((prop("Type") == "Daily Pass") ? 4 : ((prop("Type") == "Fast Pass") ? 1 : 0))

Chapters Left

Self explanatory

prop("Total Chapters") - prop("Read Chapters")

Completed?

Also self explanatory

prop("Read Chapters") >= prop("Total Chapters")

Log

It is a linked database inside a toggle, in which you can change the chapters you've read and if you want to give it priority. Those are the attributes that I consider most important when the configuration is done, but you can change the properties to your use. Also added the Total Chapters to compare if you have bad memory (like me)

Log

Webtoons